@echo off
color 0A
TITLE BILI INSTALLER V1.1
mode con: cols=45 lines=25


:: =======================================================
:: Self-elevate script to run as Administrator
:: =======================================================
:: Check if running as admin
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo [INFO] Elevating privileges to Administrator...
    powershell -Command "Start-Process '%~f0' -Verb RunAs"
    exit /b
)


:: ================== VARIABEL ==================
setlocal
set "MYDIR=%~dp0"
set "ARIA2=%MYDIR%aria2c.exe"
set "DL_DIR=%MYDIR%downloads"
set "COMMON_FLAGS=-x 16 -s 16 --check-certificate=false"
set "SEVENZIP=%DL_DIR%\7z.exe"

if not exist "%DL_DIR%" mkdir "%DL_DIR%"

:: ================== CEK ARIA2C.EXE ==================
if not exist "%ARIA2%" (
    echo aria2c.exe tidak ditemukan. Mendownload...
    powershell -Command "Invoke-WebRequest -Uri 'https://file.mocina.my.id/uploads/aria2c.exe' -OutFile '%ARIA2%'"
)

"%ARIA2%" --version >nul 2>&1
if errorlevel 1 (
    echo aria2c.exe rusak atau tidak bisa dijalankan.
    del "%ARIA2%"
    pause
    exit /b
)

:menu
cls
title Bili Installer Menu
echo ____________________________________
echo.
echo     Bili Installer Menu
echo.
echo.
echo   ________________________
echo.
echo   [1] HP MFP 183 Printer
echo   [2] EasyConnect VPN
echo   [3] O365 Online
echo   [4] WeCom
echo   [5] VC++ Runtime AIO
echo   [6] Windows Switch Version
echo   [7] Activate Windows 10 Pro (VPN needed)
echo   [8] O365 License Uninstaller
echo   [9] TightVNC - Server 
echo.
echo   ________________________
echo.
echo   [0] Exit
echo ____________________________________
echo.

set /p choice=Choose an option [0-9] :

if "%choice%"=="1" goto install_hp
if "%choice%"=="2" goto install_easyconnect
if "%choice%"=="3" goto install_o365
if "%choice%"=="4" goto install_wecom
if "%choice%"=="5" goto install_vcruntime
if "%choice%"=="6" goto switch_windows_version
if "%choice%"=="7" goto activate_windows
if "%choice%"=="8" goto uninstall_o365
if "%choice%"=="9" goto install_tightvnc
if "%choice%"=="0" exit /b 0
goto menu


:: ========== INSTALL TIGHTVNC ==========
:install_tightvnc
title Installing TightVNC...

cd /d "%DL_DIR%"

:: Download TightVNC MSI pakai aria2
"%ARIA2%" %COMMON_FLAGS% -o tightvnc.msi "https://file.mocina.my.id/uploads/tightvnc-2.8.85-gpl-setup-64bit.msi"

if not exist "%DL_DIR%\tightvnc.msi" (
    echo [ERROR] TightVNC download failed!
    pause
    goto menu
)


:: Install TightVNC with verbose MSI logging
echo [INFO] Starting TightVNC silent install...
powershell -Command "Start-Process msiexec.exe -ArgumentList '/i','%DL_DIR%\tightvnc.msi','/quiet','/norestart','ADDLOCAL=Server','SET_USEVNCAUTHENTICATION=1','SET_PASSWORD=78616a684031333134','SET_VIEWONLYPASSWORD=78616a684031333134','/L*V','%DL_DIR%\tightvnc_install.log' -Wait -PassThru"

if %errorlevel% neq 0 (
    echo [ERROR] TightVNC installation failed! Check log at %DL_DIR%\tightvnc_install.log
    pause
    goto menu
)

echo [SUCCESS] TightVNC installed successfully. Log saved at %DL_DIR%\tightvnc_install.log
pause
goto menu


:: ========== INSTALL HP PRINTER ==========
:install_hp
title Installing HP MFP 183...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o hp.exe "https://file.mocina.my.id/uploads/Full_Webpack-44.11.2784-LJM182-M185_UWWL_4_1_Full_Webpack.exe"
powershell -Command "Start-Process -FilePath '%DL_DIR%\hp.exe' -ArgumentList '/s' -Wait"
goto done

:: ========== INSTALL EASYCONNECT ==========
:install_easyconnect
title Installing EasyConnect VPN...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o vpn.exe "https://file.mocina.my.id/uploads/EasyConnectInstaller.exe"
powershell -Command "Start-Process -FilePath '%DL_DIR%\vpn.exe' -ArgumentList '/S' -Wait"
goto done

:: ========== INSTALL O365 ==========
:install_o365
title Installing Office 365...
cd /d "%DL_DIR%"

:: Download installer
"%ARIA2%" %COMMON_FLAGS% -o o365.exe "https://file.mocina.my.id/uploads/OfficeSetup.exe"

:: Download config.yml
echo Mengunduh config.yml...
"%ARIA2%" --check-certificate=false -d "%DL_DIR%" -o config.yml "https://file.mocina.my.id/uploads/config.yml"


:: Cek apakah file config.yml berhasil diunduh
if not exist "%DL_DIR%\config.yml" (
    echo Gagal mengunduh config.yml. Pastikan koneksi internet aktif.
    pause
    goto menu
)

:: Jalankan Office installer
powershell -Command "Start-Process -FilePath '%DL_DIR%\o365.exe' -ArgumentList '/configure','%DL_DIR%\config.yml' -Wait"
goto done


:: ========== INSTALL WECOM ==========
:install_wecom
title Installing WeCom...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o wecom.exe "https://file.mocina.my.id/uploads/WeCom_4.1.38.6006.exe"
powershell -Command "Start-Process -FilePath '%DL_DIR%\wecom.exe' -ArgumentList '/S' -Wait"
goto done

:: ========== INSTALL VC++ RUNTIME ==========
:install_vcruntime
title Installing VC++ Runtime AIO...
cd /d "%DL_DIR%"

:: Download 7-Zip if needed
if not exist "%SEVENZIP%" (
    echo 7z.exe tidak ditemukan. Mendownload 7-Zip portable...
    "%ARIA2%" %COMMON_FLAGS% -o "%DL_DIR%\7-Zip.zip" "https://file.mocina.my.id/uploads/7-Zip.zip"
    
    if exist "%DL_DIR%\7-Zip.zip" (
        powershell -Command "Expand-Archive '%DL_DIR%\7-Zip.zip' -DestinationPath '%DL_DIR%'"
    ) else (
        echo Gagal mengunduh 7-Zip.zip. Periksa koneksi internet.
        pause
        goto menu
    )
)

:: Download runtime ZIP
"%ARIA2%" %COMMON_FLAGS% -o vcruntime.zip "https://file.mocina.my.id/uploads/Visual-C-Runtimes-All-in-One-Jun-2025.zip"

:: Ekstrak menggunakan 7-Zip
echo Mengekstrak menggunakan 7-Zip...
"%SEVENZIP%" x "vcruntime.zip" -o"%DL_DIR%\vcruntime" -y >nul

:: Jalankan install_all.bat
if exist "%DL_DIR%\vcruntime\install_all.bat" (
    pushd "%DL_DIR%\vcruntime"
    powershell -Command "Start-Process -FilePath '%DL_DIR%\vcruntime\install_all.bat' -Wait"
    popd
) else (
    echo Gagal mengekstrak atau file install_all.bat tidak ditemukan.
    pause
)

goto done

:: ========== SWITCH WINDOWS VERSION ==========
:switch_windows_version
title Switching Windows Version...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o switch_win.bat "https://file.mocina.my.id/uploads/Switch%%20os%%20ver%%20win%%2010.bat"
powershell -Command "Start-Process -FilePath '%DL_DIR%\switch_win.bat' -Wait"
goto done

:: ========== ACTIVATE WINDOWS ==========
:activate_windows
title Activating Windows 10 Pro...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o activate_win.bat "https://file.mocina.my.id/uploads/windows_10_active_nologo.bat"
powershell -Command "Start-Process -FilePath '%DL_DIR%\activate_win.bat' -Wait"
goto done

:: ========== UNINSTALL O365 LICENSE ==========
:uninstall_o365
title Uninstalling O365 License...
cd /d "%DL_DIR%"
"%ARIA2%" %COMMON_FLAGS% -o uninstall_o365.vbs "https://file.mocina.my.id/uploads/uninstall_license_0365.vbs"
cscript //nologo uninstall_o365.vbs
goto done

:: ========== DONE ==========
:done
title Bili Installer - Done
echo.
echo === Installation Finished! Press any key to return to menu ===
pause >nul
goto menu